DC motor car

ตรวจสอบการต่อสายกับพิน ดังนี้

Arduino code สำหรับ WIFI Car

5. เขียนโค้ดดังต่อไปนี้ ลงบน Arduino IDE

อันดับแรก กำหนดตัวแปร สำหรับเรียกแทนพินต่างๆ 

#define ENA   14          // Enable/speed motors Right        GPIO14(D5)

#define ENB   12          // Enable/speed motors Left         GPIO12(D6)

#define IN_1  15          // L298N in1 motors Rightx          GPIO15(D8)

#define IN_2  13          // L298N in2 motors Right           GPIO13(D7)

#define IN_3  2           // L298N in3 motors Left            GPIO2(D4)

#define IN_4  0           // L298N in4 motors Left            GPIO0(D3)

ต่อมา นำเข้า library ที่จำเป็น เพื่อทำให้ ESP8266 เป็น wifi server

#include <ESP8266WiFi.h>

#include <WiFiClient.h> 

#include <ESP8266WebServer.h>

สร้างตัวแปร เพื่อบันทึกค่าสถานะความเร็ว และ ตำแหน่ง

String command;             //String to store app command state.

int speedCar = 800;         // 400 - 1023.

int speed_Coeff = 3;

ตั้งชื่อให้กับไวไฟ ที่มาจาก ESP8266 สามารถตั้งได้ตามใจ โดยชื่ออยู่ในเครื่องหมายคำพูด

const char* ssid = "Electroniclinic";

ESP8266WebServer server(80);

ตั้งค่าเริ่มต้นให้โปรแกรม โดยกำหนด pinMode ให้พินต่างๆ และเตรียมสำหรับการแสดงผลทาง Serial Monitor

void setup() {

 pinMode(ENA, OUTPUT);

 pinMode(ENB, OUTPUT);  

 pinMode(IN_1, OUTPUT);

 pinMode(IN_2, OUTPUT);

 pinMode(IN_3, OUTPUT);

 pinMode(IN_4, OUTPUT); 

  Serial.begin(115200);

เขียนคำสั่งเชื่อมต่อไวไฟ และเริ่ม web server ให้ทำงาน

// Connecting WiFi

  WiFi.mode(WIFI_AP);

  WiFi.softAP(ssid);

  IPAddress myIP = WiFi.softAPIP();

  Serial.print("AP IP address: ");

  Serial.println(myIP);

 // Starting WEB-server 

     server.on ( "/", HTTP_handleRoot );

     server.onNotFound ( HTTP_handleRoot );

     server.begin();    

}

สร้างฟังก์ชั่น ให้รถเดินหน้า

void goAhead(){ 

      digitalWrite(IN_1, LOW);

      digitalWrite(IN_2, HIGH);

      analogWrite(ENA, speedCar);

      digitalWrite(IN_3, LOW);

      digitalWrite(IN_4, HIGH);

      analogWrite(ENB, speedCar);

  }

สร้างฟังก์ชั่น ให้รถถอยหลัง

void goBack(){ 

      digitalWrite(IN_1, HIGH);

      digitalWrite(IN_2, LOW);

      analogWrite(ENA, speedCar);

      digitalWrite(IN_3, HIGH);

      digitalWrite(IN_4, LOW);

      analogWrite(ENB, speedCar);

  }

สร้างฟังก์ชั่น ให้รถเลี้ยวขวา

void goRight(){ 

      digitalWrite(IN_1, HIGH);

      digitalWrite(IN_2, LOW);

      analogWrite(ENA, speedCar);

      digitalWrite(IN_3, LOW);

      digitalWrite(IN_4, HIGH);

      analogWrite(ENB, speedCar);

  }

สร้างฟังก์ชั่น ให้รถเลี้ยวซ้าย

void goLeft(){

      digitalWrite(IN_1, LOW);

      digitalWrite(IN_2, HIGH);

      analogWrite(ENA, speedCar);

      digitalWrite(IN_3, HIGH);

      digitalWrite(IN_4, LOW);

      analogWrite(ENB, speedCar);

  }

สร้างฟังก์ชั่น ให้รถวิ่งไปทิศตะวันออกเฉียงเหนือ

void goAheadRight(){

      digitalWrite(IN_1, LOW);

      digitalWrite(IN_2, HIGH);

      analogWrite(ENA, speedCar/speed_Coeff);

      digitalWrite(IN_3, LOW);

      digitalWrite(IN_4, HIGH);

      analogWrite(ENB, speedCar);

   }

สร้างฟังก์ชั่น ให้รถวิ่งไปทิศตะวันตกเฉียงเหนือ

void goAheadLeft(){

      digitalWrite(IN_1, LOW);

      digitalWrite(IN_2, HIGH);

      analogWrite(ENA, speedCar);

      digitalWrite(IN_3, LOW);

      digitalWrite(IN_4, HIGH);

      analogWrite(ENB, speedCar/speed_Coeff);

  }

สร้างฟังก์ชั่น ให้รถวิ่งไปทิศตะวันออกเฉียงใต้

void goBackRight(){ 

      digitalWrite(IN_1, HIGH);

      digitalWrite(IN_2, LOW);

      analogWrite(ENA, speedCar/speed_Coeff);

      digitalWrite(IN_3, HIGH);

      digitalWrite(IN_4, LOW);

      analogWrite(ENB, speedCar);

  }

สร้างฟังก์ชั่น ให้รถวิ่งไปทิศตะวันตกเฉียงใต้

void goBackLeft(){ 

      digitalWrite(IN_1, HIGH);

      digitalWrite(IN_2, LOW);

      analogWrite(ENA, speedCar);

      digitalWrite(IN_3, HIGH);

      digitalWrite(IN_4, LOW);

      analogWrite(ENB, speedCar/speed_Coeff);

  }

สร้างฟังก์ชั่น ให้รถหยุดวิ่ง

void stopRobot(){  

      digitalWrite(IN_1, LOW);

      digitalWrite(IN_2, LOW);

      analogWrite(ENA, speedCar);

      digitalWrite(IN_3, LOW);

      digitalWrite(IN_4, LOW);

      analogWrite(ENB, speedCar);

 }

สร้างคำสั่งให้ทำซ้ำตลอด เพื่อรับค่าคำสั่ง จากแอพมือถือ 

void loop() {

    server.handleClient();

      command = server.arg("State");

      if (command == "F") goAhead();

      else if (command == "B") goBack();

      else if (command == "L") goLeft();

      else if (command == "R") goRight();

      else if (command == "I") goAheadRight();

      else if (command == "G") goAheadLeft();

      else if (command == "J") goBackRight();

      else if (command == "H") goBackLeft();

      else if (command == "0") speedCar = 400;

      else if (command == "1") speedCar = 470;

      else if (command == "2") speedCar = 540;

      else if (command == "3") speedCar = 610;

      else if (command == "4") speedCar = 680;

      else if (command == "5") speedCar = 750;

      else if (command == "6") speedCar = 820;

      else if (command == "7") speedCar = 890;

      else if (command == "8") speedCar = 960;

      else if (command == "9") speedCar = 1023;

      else if (command == "S") stopRobot();

}

void HTTP_handleRoot(void) {

if( server.hasArg("State") ){

       Serial.println(server.arg("State"));

  }

  server.send ( 200, "text/html", "" );

  delay(1);

}

ดาวน์โหลด แอพมือถือ สำหรับควบคุมรถ

• คลิกที่ลิ้งค์นี้ mobile app control car --> เพื่อดาวน์โหลดโปรแกรมแอพมือถือ ไว้ในคอมพิวเตอร์ก่อน

• ส่งไฟล์ที่ดาวน์โหลดมาแล้ว ไปที่อีเมล์ของนักเรียนเอง ซึ่งเป็นอีเมล์ที่แน่ใจว่า สามารถเปิดได้ผ่านมือถือตนเอง

• ใช้มือถือ เปิดอ่านอีเมล์ที่ส่งมาดังกล่าว เพื่อทำการติดตั้งไฟล์ที่แนบมากับอีเมล์ ลงบนมือถือ

เชื่อมต่อ แอพมือถือ กับ รถ wifi car

1. เปิดสวิทช์ถ่านที่รถไวไฟ

2. เปิดไวไฟในมือถือของนักเรียน

3. ค้นหาชื่อไวไฟที่ได้ตั้งไว้ในโค้ดข้างต้น ซึ่งจะเป็นไวไฟจากรถ และทำการเชื่อมต่อกับโทรศัพท์

4. เปิดแอพควบคุมรถขึ้นมา

5. เริ่มกดปุ่มเพื่อลองควบคุมรถได้เลย

6. เสร็จสิ้นโปรเจค